serveur hijal HORDE
 
AccueilCalendrierFAQRechercherMembresS'enregistrerConnexion

Partagez | 
 

 [Guide] Macros

Aller en bas 
AuteurMessage
Invité
Invité



MessageSujet: [Guide] Macros   Ven 27 Sep - 18:49

Yop. Comme promis, je poste ici ce guide sur les macros que j'avais rédigé pour une autre guilde (NextGaymer - Hyjal) il y a quelques temps.

Déjà, sachez que les macros dans Wow n’ont rien d’indispensable, mais qu'elles ont un aspect très pratique quand on sait les utiliser. Au début, ça peut faire peur, mais c’est vraiment tout bête une fois qu’on a pigé le truc.


Sommaire :
1.1- Qu’est-ce qu’une macro ?
1.2- Possibilités et limites
1.3- Comment créer une macro ?
1.4- Commandes, Méta-commandes et Touches modificatrices
1.5- Conditions et Mouseover
1.6- Exemples de macros utiles
1.7- Pourquoi ça marche pô ?


1.1 – Qu’est-ce qu’une macro ?

Une macro est une ligne de script, ou un ensemble de lignes, qui permet d’exécuter une ou plusieurs actions en jeu.
La plupart d’entre-vous utilisent déjà des lignes de script sans s’en rendre compte, avec les actions de dialogue « /parler », « /incliner », « /dormir », etc… Les macros que vous pouvez créer via l’outil de macros reposent exactement sur le même principe.

Les macros se présentent de plusieurs façons :
- Macro simple sans condition (Action directe) :
/commande Action
- Macro simple avec condition (Si > Alors)
/commande 0]cible,condition] Action
- Macro complexe avec conditions et actions en conséquence (Si > Alors > Sinon)
/commande 0]cible_1,condition_1]Action_1; 0]cible_2,condition_2]Action_2

Légende de couleurs
Orange : Commandes
Violet : Cibles (optionnelles)
Bleu : Conditions (optionnelles)


1.2 Possibilités et limites

On ne peut pas tout faire avec des macros sur Wow, mais il y a quand même beaucoup de fonctionnalités qui rendent la vie plus facile. Déjà, sachez que les macros en jeu ne vous permettent pas de passer outre certaines limites (notamment le GCD, c'est à dire le temps de recharge partagé par la majorité de vos techniques et objets), et qu’elles ne peuvent se déclencher qu’en réponse à une action de votre part (clic de souris ou touche de clavier). Aucune action ne permet de lancer une macro de manière indépendante et automatique, ni de répéter une même macro en boucle en ne cliquant qu’une seule fois dessus.

Une macro fonctionne comme une technique en jeu : elle ne s’exécute que si l’action est possible et réalisable à l’instant où vous cliquez sur son icône, ni avant, ni après.

Ce que vous ne pouvez pas faire avec une macro :
- Lancer plusieurs techniques soumises au GCD en même temps.
- Retarder le lancement d’une technique.
- Vérifier les points de vie et les ressources d’une unité (mana, énergie, rage, points de combo ou de chi, etc…).
- Vérifier les buffs / débuffs présents sur une unité.
- Vérifier une distance
- Créer un timer
- Vérifier le niveau d’une cible

Les seules conditions possibles sont de type booléennes, reposant sur le principe du « Vrai ou Faux ». Par exemple :
- si la cible est amicale ou non (idem pour les cibles hostiles)
- si la cible est en vie ou non
- si vous ciblez une unité ou non
- si la cible est dans votre groupe ou non
- si la cible est en combat ou non
- si la cible est en train de voler ou non
- etc...

Les macros permettent en revanche de lancer en même temps plusieurs techniques qui ne sont pas soumises au GCD, en particulier vos boosts et techniques de survie. De même, il est tout à fait possible de créer des macros de séquence qui permettent de définir une liste de sorts, d'objets ou de techniques qui seront exécutées dans l'ordre, une à la fois par clic sur la macro.
Les macros de séquence ne permettent pas de contourner la règle du GCD, et de plus, un bug interne du jeu empêche le fonctionnement correct des macros de séquence avec les sorts non-soumis au GCD.

Enfin, vous pouvez ajouter une touche modificatrice à une macro, pour lancer plusieurs sorts différents en fonction de la touche sur laquelle vous appuyez (Shift, Maj, CTRL, etc…).

Ca peut paraître difficile, mais c’est en fait très simple. Je vais vous expliquer ça plus en détail dans la partie suivante.


1.3 Comment créer une macro ?

Ouvrez votre menu et cliquez sur « Macro » pour ouvrir l’interface de créations de macros. Ce menu propose les options suivantes :
- Macros générales : Ces macros sont accessibles pour tous les personnages existant sur le compte. Leur nombre est limité à 35.
- Macros de personnage : Ces macros ne sont accessibles que pour le personnage que vous contrôlez actuellement. Leur nombre est limité à 15.
- Modifier Nom / Icône : Ouvre le volet de personnalisation d’une macro, permettant de changer son nom et son icône. Ceci ne modifie en rien le script de la macro.
- Suppr. : Supprime définitivement une macro.
- Nouvelle : Crée une nouvelle macro (si vous avez atteint le seuil maximal ou si vous êtes en train de personnaliser une macro, cet onglet sera grisé).
- Annuler : Retour au menu du jeu.

Créez une nouvelle macro, choisissez-lui un icône et un nom, et passons à l’étape suivante.


1.4 Commandes, Méta-commandes et Touches modificatrices

Vous pouvez désormais entrer votre script dans le champ de texte se trouvant en bas de l’interface.
Sachez que toutes les lignes de script que vous entrerez devront commencer par « / » pour être valides, à l’exception des méta-commandes optionnelles qui devront toujours occuper la première ligne de votre macro et commencer par « # ».

Votre macro s’exécute ligne par ligne en partant de la première. Si une ligne n’est pas valide, les lignes suivantes s’exécuteront quand même.
Attention, il y a des conditions :
- si vous entrez plusieurs lignes pour lancer plusieurs techniques ayant un GCD, seule la première sera prise en compte, que le sort réussisse ou non.
- si vous entrez une ligne pour lancer une technique ayant un GCD mais que cette dernière échoue, le GCD sera quand même déclenché.

Le nombre maximum de caractères dans une même macro est limité à 256 !


Méta-commandes
Il en existe 3 différentes mais vous ne pouvez en utiliser qu'une par macro, elles sont à placer dans la première ligne de votre macro pour s’exécuter. Les méta-commandes permettent d’afficher ou non le temps de recharge de la technique rattachée à votre macro, ainsi que son nom et son icône.
Par défaut, votre macro utilisera les paramètres que vous avez entrés dans l'interface de macro, à savoir son icône et son nom. Vous pouvez modifier cela grâce aux méta-commandes.

Afficher le nom et le temps de recharge de la technique exécutée par votre macro :
Code:
#showtooltip
Afficher uniquement le temps de recharge de la technique :
Code:
#showcooldown
Afficher le nom et le temps de recharge de la technique de son choix (elle doit être connue par votre personnage) :
Code:
#show Nom_de_la_technique
Notez que si vous définissez vous-même l'icône d'une macro, la méta-commande ne pourra pas la modifier. Pour faire apparaître l'icône de la ou des techniques associées à une macro, il faut sélectionner l'icône vierge "?" dans le menu "Modifier nom / icône".


Commandes
Ensuite, il est temps d’attaquer le gros morceau, à savoir les commandes « / ». Elles sont regroupées dans plusieurs catégories (liste non-exhaustive !) :

- Commandes de ciblage
/target Nom de la cible : Cible l’unité portant le nom que vous avez choisi. Vous pouvez entrer un nom incomplet pour cibler l’unité proche dont le nom comporte les caractères que vous avez défini.
/targetenemy : Cible l’unité hostile la plus proche devant vous. Entrez le nom d’un ennemi pour cibler ce dernier.
/targetenemyplayer : Cible le joueur hostile le plus proche devant vous. Entrez le nom d’un joueur ennemi pour cibler ce dernier.
/targetfriend : Cible l’unité amicale la plus proche devant vous. Entrez le nom d’une cible amicale pour cibler cette dernière.
/targetlastenemy : Sélectionne la dernière unité ennemie que vous avez ciblée.
/targetlastfriend : Sélectionne la dernière unité amicale que vous avez ciblée.
/targetlasttarget : Sélectionne la dernière unité amicale ou hostile ciblée par votre cible.
/focus : Définit une cible comme étant une cible secondaire. Entrez le nom d’une unité amicale ou hostile pour garder son portrait en focalisation.
/assist : Sélectionne la cible d’un joueur
/cleartarget : Efface la cible actuelle
/clearfocus : Efface la cible secondaire
/targetparty : Cible un membre du groupe. Si vous n’entrez pas de nom, cible le membre du groupe le plus proche devant vous.
/targetraid : Cible un membre du raid. Si vous n’entrez pas de nom, cible le membre du raid le plus proche devant vous.

- Commandes de familier
/petattack : Ordonne à votre familier d’attaquer votre cible
/petautocaston : Active l’attaque ou l’incantation automatique de votre familier.
/petautocastoff : Désactive l’attaque ou l’incantation automatique de votre familier.
/petfollow : Ordonne à votre familier de vous suivre.
/petstay : Ordonne à votre familier de rester sur place.

- Commandes d’attaque
/startattack : Engage l’attaque automatique contre votre cible.
/stopattack : Annule l’attaque automatique.
/cast Nom_du_sort : Lance le sort de votre choix (le nom du sort doit être exact)
/stopcasting : Interrompt l’incantation d’un sort.
/cancelaura Nom_de_l’effet : Supprime une amélioration vous affectant (ne fonctionne pas avec les débuffs ennemis)
/use Nom_de_l’objet : Utilise l’objet choisi (le nom de l’objet doit être exact)
/castrandom Sort1, Sort2, SortX : Lance un sort aléatoire dans la liste donnée (remplacer Sort1, 2, X par le nom d’un sort. Ceci consommera un GCD)
/castsequence Sort1, Sort2, SortX : Lance les sorts dans l’ordre précis que vous avez défini (remplacer sort1, 2, X par le nom d’un sort. Ceci consommera un GCD)

- Commandes de messages
/d Texte : Affiche en message simple le texte choisi. Remplacer Texte par votre message
/cri Texte : Votre personnage crie le texte choisi. Remplacer Texte par votre message
/gr : Affiche un message en canal de groupe.
/raid : Affiche un message en canal de raid.
/reply : Répond à la dernière personne qui vous a chuchoté.
/o : Bascule en canal officier.
/g : Bascule en canal de guilde.
/run p={"Texte1","Texte2","TexteX"} : Génère une liste de messages. Remplacer Texte par votre message. Chaque phrase doit être entre guillemets et séparée par une virgule.
/run SendchatMessage(p[random(1,X)]) : Fait prononcer une phrase aléatoire parmi celles que vous avez générée. Le nombre X doit être égal au nombre de messages que vous avez défini dans la commande précédente.

- Autres commandes
/stopmacro : Interrompt la macro en cours
/dismount : Descend de monture

Je passe volontairement sur les commandes diverses (parler/ manger, etc…). Notez toutefois que vous pouvez vous en servir dans vos macros pour faire agir votre personnage de la façon qu’il vous conviendra.


Touches modificatrices
Vous pouvez utiliser une macro pour lancer plusieurs sorts différents en leur attribuant une touche additionnelle. Par exemple, je désire lancer « Boule de feu » quand je clique sur ma macro, et « Explosion pyrotechnique » quand je clique dessus en maintenant également « Shift » enfoncée.

La commande à rajouter à une ligne pour appliquer une touche modificatrice est la suivante :
Code:
[mod:ma_touche_modificatrice]
Pour être prise en compte, elle doit être placée après la commande d’incantation « /cast », séparée d’un espace.
J’obtiens donc ceci
Code:
/cast [mod:shift]Explosion pyrotechnique; Boule de feu
Vous pouvez remplacer Shift par Alt ou CTRL, selon votre choix. Le sort indiqué en premier, juste après la commande, sera la sort qui se déclenchera quand vous appuierez sur la touche correspondante.


1.5 Conditions et Mouseover

Vous pouvez complexifier une macro pour lui demander de vérifier certains points avant d’autoriser une action. Toute condition intégrée à une macro repose sur le principe booléen du Vrai ou Faux, il est impossible de vérifier un nombre réel (comme les points de vie, voir 1.2).

Une condition s’intègre toujours après une commande, séparée d’un espace et placée entre crochets []. Vous pouvez définir une condition unique ou un ensemble de conditions de cette façon.
Voici quelques exemples de possiblités :
Lancer un sort si une condition unique est respectée, ne rien faire sinon
Code:
/cast [condition_1]Sort 1
Lancer un sort A si une condition unique est respectée, sinon lancer un sort B
Code:
/cast [condition_1]Sort A; Sort B
Lancer un sort A si une condition 1 est respectée, ou lancer un sort B si une condition 2 est respectée. Ceci lancera le sort A si la première condition est respectée, sinon il lancera le sort B si la condition 2 est respectée, sinon il ne fera rien.
Code:
/cast [condition_1]Sort A; [condition_2]Sort B
Lancer un sort A si un groupe de conditions est respecté, sinon lancer un sort B
Code:
/cast [condition_1,condition_2]Sort A; Sort B
Lancer un sort A si un groupe de conditions est respecté, sinon lancer un sort B si une condition 3 est respectée, sinon lancer un sort C
Code:
/cast [condition_1,condition_2]Sort A; [condition_3]Sort B; Sort C
La syntaxe est extrêmement importante dans les conditions. Chaque bloc [] est indépendant des autres, et ce sera toujours le premier bloc de la ligne qui sera analysé en priorité. La virgule qui sépare les conditions dans un même bloc fait office de ET, et non de OU. Autrement dit, si l’une des conditions d’un même bloc n’est pas validée, votre macro passera immédiatement au bloc suivant.
Il reste toutefois possible de regrouper plusieurs conditions dans un même bloc, et d'exécuter l'action si au moins une des conditions de ce même bloc est remplie. La virgule cède alors la place au slash ( / ), de ce fait votre macro va inspecter chacune des conditions du bloc et validera ce dernier si au moins une des conditions demandées est remplie.

Donc pour rappel :
Virgule ( , ) : ET
Slash ( / ) : OU

De même, il ne doit pas y avoir d'espace avant ou après une virgule ou un slash dans une condition.

Vous pouvez également choisir entre plusieurs conditions pour une même action, et exécuter cette dernière si au moins l’une des conditions est respectée. Dans ce cas, on inscrit chaque condition dans un bloc à part et on colle les blocs les uns aux autres sans espace.
Attention toutefois, la priorité est toujours donnée à la première condition, puis à la deuxième, etc... Quand l'une des conditions est remplie, la commande exécutera l'action pour la cible répondant à la condition et ignorera totalement les suivantes.
Code:
/cast [condition_1][condition_2] Sort A
Votre condition peut être précédée d’une cible. Vous définirez cette dernière par un @. Par exemple :
@player : Vous-même
@target : Votre cible actuelle
@focus : Votre cible secondaire
@pet : Votre familier
@targettarget : La cible de votre cible
@pettarget : La cible de votre familier
@mouseover : La cible se trouvant sous le pointeur de votre souris.

Après avoir défini votre cible, vous pouvez exiger des conditions. Intégrez ces dernières à votre bloc de conditions juste après votre cible, séparées d’une virgule sans espace. Quelques exemples de conditions :
Exists : Vérifie si vous avez une cible
Help : Vérifie si la cible est amicale
Harm : Vérifie si la cible est hostile
Dead : Vérifie si la cible est morte
Combat : Vérifie si la cible est en combat
Party : Vérifie si la cible est dans votre groupe
Raid : Vérifie si la cible est dans votre raid
Channeling : Vérifie si une canalisation est en cours
Flying : Vérifie si la cible est en train de voler
Stealth : Vérifie si la cible est camouflée
Outdoors : Vérifie si la cible se trouve en extérieur (Indoors : en intérieur)
Stance : Vérifie la posture / forme de la cible (voir ci-dessous)
Button:X : Vérifie le bouton de la souris (Remplacer X par 1 pour clic gauche, et 2 pour clic droit)

Pour vérifier l’inverse d’une condition, précédez cette dernière par « no » (exemple : nodead pour vérifier une cible qui n’est pas morte, noexists pour vérifier que vous n'avez pas de cible, etc...).

Postures :
Pour les joueurs jouant une classe pouvant adopter des postures ou se métamorphoser, la condition "Stance" regroupe et numérote les différentes postures et formes de chaque classe. Cette condition s'emploie de cette manière :
Stance:X/Y/n

Selon le nombre de postures que vous voulez vérifier, il faudra remplacer les caractères par des numéros en les séparant tous d'un slash sans espace. Ainsi, pour un guerrier par exemple, si vous écrivez "Stance:0/2", le jeu va vérifier que votre guerrier adopte la posture défensive (2) ou pas de posture du tout (0). S'il est en posture Berserker par exemple, la condition ne sera pas remplie.

Les numéros des postures par classes :
• Guerrier
- 0 : pas de posture
- 1 : posture de combat
- 2 : posture défensive
- 3 : posture berserker

• Druide
- 0 : pas de forme
- 1 : forme d'ours
- 2 : forme aquatique
- 3 : forme de félin
- 4 : forme de voyage
- 5 : forme de sélénien
- 6 : forme de vol rapide

• Prêtre
- 0 : pas de forme
- 1 : forme d'ombre / d'esprit de rédemption

• Voleur
- 0 : pas de posture
- 1 : camouflage
- 3 : danse de l'ombre

• Chaman
- 0 : pas de forme
- 1 : loup fantôme

• Démoniste
- 0 : pas de forme
- 1 : métamorphe


Exemple : Lancer le sort Purifier sur ma cible uniquement si elle est alliée et en vie, sinon ne rien faire, et dire à mon groupe que j’ai purifié ma cible.
Code:
#showtooltip
/cast [@target,help,nodead]Purifier
/gr Purifier sur %t
Note : %t sera automatiquement remplacé par le nom de votre cible actuelle. Vous pouvez également afficher le nom de votre cible en focus en remplaçant %t par %f.

A ce stade-là, soit vous avez tenu le coup avec de l’aspirine, soit vous vous êtes déjà pendu. Rassurez-vous, on va résumer tout ça dans un exemple :
Je souhaite créer une macro qui lance le sort « Soin » sur ma cible si elle est alliée et en vie, ou le sort « Mot de l’ombre : douleur » si ma cible est hostile et en vie.
Code:
#showtooltip
/cast [@target,nodead,help]Soin; [@target,nodead,harm]Mot de l’ombre : Douleur
Autre exemple, je veux créer une macro qui va lancer Pénitence sur la cible que je pointe à la souris (mouseover), sinon sur ma cible actuelle, sinon sur moi :
Code:
#showtooltip
/cast [@mouseover,exists][@target,exists,nodead][@player]Pénitence
Cette macro va procéder de la façon suivante :
- si vous avez pointez une cible tout en ayant une autre sélectionnée, le sort partira sur celle que vous pointez
- si vous ne pointez pas de cible avec votre souris, le sort partira sur la cible sélectionnée
- si vous n'avez pas de cible sélectionnée et que vous ne pointez personne à la souris, le sort partira sur vous-même

N'oubliez pas l'ordre de priorités. Si un bloc de condition est valide, peu importe les suivants, votre macro déclenchera le sort pour la cible répondant à la condition. Pour lancer un sort sur une cible pointée à la souris plutôt qu'à votre cible principale, il faut donc définir le mouseover comme prioritaire, faute de quoi votre sort partira toujours sur votre cible principale.


Vous noterez l’apparition de « mouseover », qui va prendre pour cible l’unité que je pointe avec ma souris, sans sélectionner cette dernière. Cette fonctionnalité permet de changer de cible facilement juste en la pointant avec la souris, ou en pointant sa barre de vie.
Le mouseover fonctionne avec toutes les unités que vous pouvez sélectionner normalement, qu'elles soient amicales, neutres ou hostiles. Combiné à des raccourcis clavier, le mouseover offre une grande liberté et une très bonne réactivité en combat, permettant d'attaquer ou de soigner n'importe quelle cible tout en gardant votre cible principale en sélection.

Cette fonction impose toutefois de jouer avec des raccourcis, car vous ne pouvez pointer une cible avec votre souris et cliquer sur le sort dans votre barre d'action en même temps.
Admettons que vous avez défini en raccourci plusieurs sorts de votre barre d'action, on va prendre par exemple A pour Eclair de givre, E pour Javelot de glace et R pour Trait de feu (on supposera ici que vous vous déplacez avec ZQSD).

Pour améliorer l'efficacité de vos sorts couplés à des raccourcis, on va leur ajouter une fonction mouseover.
Eclair de givre
Code:
#showtooltip
/cast [@mouseover,harm,nodead][@target,exists]Éclair de givre
Placez cette macro dans votre barre de sorts à la place d’Éclair de givre. Elle continuera de lancer le sort sur votre cible principale quand vous appuierez sur A, sauf si vous pointez une autre cible ennemie avec votre souris (le sort sera alors lancé sur cette dernière sans désélectionner votre cible principale).
Répétez cette opération pour tous vos sorts assignés à des raccourcis clavier, et vous obtiendrez ainsi une panoplie de sorts que vous pourrez lancer sur n'importe quel ennemi à portée juste en les pointant à la souris, sans perdre de vue votre cible principale.


1.6 Exemples de macros

Si vous avez bien suivi tout ce qui a été expliqué dans ce zôli guide, vous devriez normalement avoir compris le système des macros. Voici une liste non-exhaustive de macros utiles et/ou amusantes que vous pouvez créer.


Macros générales > Focus
• Annuler une cible puis cibler l'ennemi le plus proche et se mettre en mode attaque automatique (combiné à une touche de la souris, ceci peut offrir une alternative pratique à la touche TAB)
Code:
/cleartarget
/targetenemy
/startattack
• Définir votre cible actuelle comme cible secondaire (focus), si vous n'avez pas déjà de cible secondaire.
Code:
/focus [target=focus,noexists]
• Définir l'unité que vous pointez à la souris comme étant votre cible secondaire
Code:
/focus [target=mouseover,exists,nodead]
• Définir un membre du groupe comme étant votre cible secondaire. Remplacer "N" par le numéro du joueur dans le groupe (le premier membre du groupe 1 porte le n°1, le premier membre du groupe 2 porte le n°6, etc...)
Code:
/focus [@partyN,exists,nodead]
• Appliquer un icône de raid à votre cible principale et annoncer à votre groupe d'attaquer cette dernière (le X est à remplacer par un nombre de 1 à 8 selon l'icône désiré : 1 Etoile / 2 Rond / 3 Losange / 4 Triangle / 5 Lune / 6 Carré / 7 Croix / 8 Crâne)
Code:
/run SetRaidTarget("target",X)
/gr Attaquez %t !
/raid Attaquez %t !
Macros générales > Sorts et techniques
• Définir une séquence de sorts à utiliser dans un ordre précis, puis réinitialiser la séquence après 3 secondes. Note : les sorts ne se déclencheront pas tous seuls, vous devrez cliquer sur votre macro ou utiliser un raccourci pour chaque sort.
Code:
#showtooltip
/castsequence reset=3 Toucher vampirique, Mot de l'ombre : Douleur
• Lancer un sort seulement si aucune canalisation n'est en cours.
Code:
#showtooltip
/cast [nochanneling]Incandescence mentale
• Interrompre une incantation pour lancer un sort A puis un sort B sur votre cible principale ou sur l'unité que vous pointez à la souris. Réinitialiser la séquence à chaque changement de cible ou au bout de 5 secondes.
Code:
#showtooltip
/stopcasting
/castsequence reset=5/target [@mouseover,help][@target,help]Soins, Soins supérieurs
• Interrompre une incantation pour lancer un contresort et indiquer au raid qu'un sort a été interrompu (Remplacer Contresort par votre technique d'interruption)
Code:
#showtooltip
/stopcasting
/cast Contresort
/raid "Contresort lancé !"
• Dissiper une cible alliée avec un clic gauche, et se dissiper soi-même avec un clic droit (Remplacer Purifier par votre sort de dissipation)
Code:
#showtooltip
/cast [button:2,target=player]Purifier; Purifier
• Descendre d'une monture uniquement au sol, et chevaucher une monture aléatoire volante (Remplacer Monture_N par le nom exact des montures désirées. Attention à la limite de caractères)
Code:
#showtooltip
/dismount [mounted,noflying]
/castrandom [nomounted,flyable]Monture_1, Monture_2, Monture_3, etc...
• Réinitialiser votre cible secondaire + générer une nouvelle cible secondaire selon votre cible principale ou celle que vous pointez à la souris
Code:
/clearfocus
/focus [@mouseover,help,nodead][@target,help]
• Prêtre discipline : Soins supérieurs sur cible principale ou cible secondaire (focus) si shift enfoncée + Focalisation intérieure sans affichage du message d'erreur
Code:
#showtooltip
/script UIErrorsFrame:Hide()
/cast Focalisation intérieure
/script UIErrorsFrame:Clear()
/script UIErrorsFrame:Show()
/cast [@focus,mod:shift][@target,exists]Soins supérieurs
Note : Vous pouvez répéter cette macro pour tous vos sorts de soins

• Ressusciter un membre et annoncer son nom dans un message aléatoire. Empêcher le déclenchement du message si vous ne ciblez pas un allié mort (Remplacer Résurrection par le nom de votre sort si vous n'êtes pas prêtre).
Code:
#showtooltip
/cast [@target,help,dead]Résurrection
/stopmacro [noexists][nodead][harm]
/run p={"Reviens parmi nous, %t","Résurrection : %t","Debout, %t"}
/run SendChatMessage(p[random(1,3)])
• Lancer un sort bénéfique sur la cible pointée à la souris, sinon sur soi-même
Code:
#showtooltip
/cast [@mouseover,help,nodead][@player]Nom_du_sort
• Lancer un sort si aucune canalisation est en cours :
Code:
#showtooltip
/cast [@target,nochanneling]Nom_du_sort
• Toucher vampirique + Mot de l'ombre : douleur en séquence de cast, réinitialisé au changement de cible
Code:
#showtooltip
/castsequence reset=3/target [@mouseover,exists][@target,exists]Toucher vampirique, Mot de l'ombre : Douleur
• Interrompre un sort pour lancer Contresort sur une cible en focus, et indiquer le nom de cette dernière à votre groupe (remplacer focus par target et %f par %t si vous voulez appliquer la macro à votre cible principale).
Code:
#showtooltip
/stopcasting
/cast [@focus,exists,nodead]Contresort
/gr Contresort sur %f
/raid Contresort sur %f
• Supprimer rapidement un effet bénéfique sans faire de clic droit sur l'icône du buff.
Code:
/cancelaura Nom_de_l'effet
Note : Vous pouvez ajouter plusieurs lignes /cancelaura pour supprimer en une fois plusieurs effets bénéfiques.

• Forcer un familier à attaquer à chaque fois que vous lancez un sort ou une technique précise.
Code:
#showtooltip
/cast Nom_du_sort
/petattack
Note : Vous pouvez répéter cette macro pour chacun de vos sorts


1.7 Pourquoi ça marche pô ?

Comme je l'ai déjà précisé plus haut, la syntaxe est très importante dans un script. La plupart de vos erreurs viendront d'une virgule ou d'un espace mal placé après un caractère.
Ensuite, il ne faut pas oublier que les macros ne permettent pas de passer outre les limites imposées par le jeu, notamment en ce qui concerne le lancement de techniques multiples ou l'utilisation d'objets possédant un temps de recharge global (GCD).

Vos lignes de script s'exécutent instantanément au moment où vous cliquez dessus, je rappelle donc une fois encore qu'on ne peut pas créer de timer et qu'il n'est donc pas possible d'exécuter le lancement de plusieurs techniques à GCD à l'aide d'un seul clic sur une macro.
Revenir en haut Aller en bas
 
[Guide] Macros
Revenir en haut 
Page 1 sur 1
 Sujets similaires
-
» [Guide] Donjon bulbes et sort de capture d'ames
» [RP] Guide de l'Eglise
» Le guide du Vagabond (Niveaux 0)
» Le Guide du Receleur
» Guide d'achat Maison Martell

Permission de ce forum:Vous ne pouvez pas répondre aux sujets dans ce forum
hærmøny :: La Bibliothèque :: Addons et Interface-
Sauter vers: